数式パズル - しばっち

2025/09/14 (Sun) 07:33:53

数式パズル


実行すると下記のような問題をファイルに出力します。

数字の間にプラス(+)かマイナス(-)を入れて
数式を完成させるパズルです。

※テキストエディタで開くか印刷してから利用してください。


問題

8 6 8 9 = 1
6 6 9 7 = 10
1 4 8 6 = 7
4 9 2 8 = 1
3 6 5 8 = 12

RANDOMIZE
LET N=4 ! 項数
DIM NUM(N),SIGN(N)
OPEN #1:NAME "数式パズル問題.txt"
OPEN #2:NAME "数式パズル解答.txt"
ERASE #1
ERASE #2
FOR J=1 TO 20 ! 問題数
DO
LET SUM=0
FOR I=1 TO N
LET NUM(I)=INT(RND*9+1)
IF I=1 THEN
LET SIGN(1)=1 ! 先頭はプラス
ELSE
LET SIGN(I)=(-1)^INT(2*RND)
END IF
LET SUM=SUM+NUM(I)*SIGN(I)
NEXT I
LOOP WHILE SUM<0 OR SUM>20 ! 0～20迄の範囲
FOR I=1 TO N
PRINT #1:NUM(I);
NEXT I
PRINT #1:"=";SUM
FOR I=1 TO N
LET S=SIGN(I)
IF I>1 THEN
IF S>0 THEN PRINT #2:"+"; ELSE PRINT #2:"-";
END IF
PRINT #2:NUM(I);
NEXT I
PRINT #2:"=";SUM
NEXT J
CLOSE #1
CLOSE #2
END


解答

8 - 6 + 8 - 9 = 1
6 + 6 - 9 + 7 = 10
1 + 4 + 8 - 6 = 7
4 - 9 - 2 + 8 = 1
3 + 6 - 5 + 8 = 12
------------------------------------------------------------------------------
DLLによるパーサー(数式解析器)を利用して
足し算と引き算に掛け算と割り算にかっこも使用した
問題をファイルに出力します。

プログラムが手抜きなので表記のおかしなところもありますが
難易度は格段に上がるかと思います。

更に(%)剰余、(^)ペキ乗、(&)and演算、(|)or演算も追加できます。



問題

7 6 7 1 = 1
10 6 10 5 = 15
9 4 2 10 = 1
4 5 4 4 = 1
9 1 5 2 = 9
2 6 6 8 = 1
2 5 5 2 = 2
1 1 3 3 = 13
4 7 5 4 = 0
1 3 7 9 = 1


VC++2022でコンパイルしました。
下記からダウンロードしてください。parser.zip

https://106.gigafile.nu/1113-b721e75329147bc93b924352188c2f121

ダウンロード期限：2025年11月13日(木)

ダウンロードパス:設定していません


ヘッダーライブラリーです。(インクルードするだけで使えます)
下記からダウンロードしてこの下にあるcppソースからコンパイルできます。

https://www.partow.net/programming/exprtk/index.html#downloads
https://github.com/ArashPartow/exprtk/tree/master


RANDOMIZE
LET N=4
DIM TERM$(N),NUM$(N),K$(N),KK$(N)
LET A$="+-*/"
! A$="+-*/%^&|"
OPEN #1:NAME "数式パズル問題.txt"
OPEN #2:NAME "数式パズル解答.txt"
ERASE #1
ERASE #2
FOR J=1 TO 50
DO
DO
IF RND<.5 THEN
MAT KK$=NUL$
DO
MAT K$=NUL$
LET P1=INT(RND*N+1)
LET K$(P1)="("
LET P2=INT(RND*N+1)
LOOP WHILE P1>=P2
LET KK$(P2)=")"
END IF
LET ER=0
FOR I=1 TO N
LET P=INT(RND*LEN(A$)+1)
LET TERM$(I)=A$(P:P)
IF TERM$(I)="^" AND ER=0 THEN LET ER=1
LET NUM$(I)=STR$(INT(10*RND+1))
NEXT I
LOOP UNTIL ER=0
LET FORMULA$=""
LET F$=""
FOR I=1 TO N-1
LET FORMULA$=FORMULA$&K$(I)&NUM$(I)&KK$(I)&TERM$(I)
LET F$=F$&NUM$(I)&" "
NEXT I
LET FORMULA$=FORMULA$&NUM$(N)
LET F$=F$&NUM$(I)
CALL PARSER(FORMULA$,ANS,ERR)
LOOP UNTIL ERR=0 AND ANS>=0 AND ANS<=100 AND FP(ANS)=0
PRINT #2:FORMULA$;" =";ANS
PRINT #1:F$;" =";ANS
NEXT J
CLOSE #1
CLOSE #2
END

EXTERNAL SUB PARSER(X$,ANS,ERR)
OPTION CHARACTER BYTE
LET ERR$=REPEAT$(" ",4)
IF X$="" THEN
LET ERR=1
LET ANS=0
EXIT SUB
END IF
LET ANS=PARSER16(LCASE$(X$),ERR$)
LET ERR=INT32(ERR$)

FUNCTION PARSER16(X$,ERR$)
ASSIGN ".\DLL\parser-exprtk.dll","parser16",FPU
END FUNCTION
END SUB

EXTERNAL FUNCTION INT32(S$)
OPTION CHARACTER BYTE
FOR I=1 TO 4
LET N=N+256^(I-1)*ORD(S$(I:I))
NEXT I
LET INT32=MOD(N+2^31,2^32)-2^31
END FUNCTION
------------------------------------------------------------------------------
parser-exprtk.cpp

#include <cstdio>
#include <cmath>
#include <string>
#include <exprtk.hpp>

using namespace std;

extern "C" __declspec(dllexport) double parser16(char *input,int *err)
{
typedef exprtk::symbol_table<double> symbol_table_t;
typedef exprtk::expression<double> expression_t;
typedef exprtk::parser<double> parser_t;

double y;
string expression_string = input;

symbol_table_t symbol_table;
symbol_table.add_constants();

expression_t expression;
expression.register_symbol_table(symbol_table);

parser_t parser;
try {
if (parser.compile(expression_string,expression)) {
y = expression.value();
*err=0;
return y;
}
*err=1;
return 0;
} catch(...) {
*err=1;
return 0.0;
}
}

解答

7&6*7-1 = 1
10%(6*10)+5 = 15
9|(4-2)&10 = 1
4*(5|4)|4 = 1
9^(1%5)^2 = 9
(2|6)*6|8 = 1
2^(5|5)^2 = 2
1+(1+3)*3 = 13
4%(7&5)&4 = 0
1+(3+7)&9 = 1
------------------------------------------------------------------------------
数式解析にSAMPLEフォルダ内のINTERPRE.basを使用してみました。



DECLARE EXTERNAL FUNCTION interpreter.expression ! 数値式を評価する関数
DECLARE EXTERNAL STRING interpreter.s$ ! 入力行
DECLARE EXTERNAL NUMERIC interpreter.i ! 入力行の文字位置
DECLARE EXTERNAL NUMERIC interpreter.ERR
DECLARE EXTERNAL SUB interpreter.skip ! 空白文字を読み飛ばす副プログラム
RANDOMIZE
LET N=4
DIM TERM$(N),NUM$(N),K$(N),KK$(N)
LET A$="+-*/"
! A$="+-*/%\^&|<>@"
OPEN #1:NAME "算数パズル問題.txt"
OPEN #2:NAME "算数パズル解答.txt"
ERASE #1
ERASE #2
FOR J=1 TO 50
DO
DO
MAT KK$=NUL$
IF RND<.5 THEN
DO
MAT K$=NUL$
LET P1=INT(RND*N+1)
LET K$(P1)="("
LET P2=INT(RND*N+1)
LOOP WHILE P1>=P2
LET KK$(P2)=")"
END IF
LET ER=0
FOR I=1 TO N
LET P=INT(RND*LEN(A$)+1)
LET TERM$(I)=A$(P:P)
IF TERM$(I)="^" AND ER=0 THEN LET ER=1
LET NUM$(I)=STR$(INT(10*RND+1))
NEXT I
LOOP UNTIL ER=0
LET S$=""
LET F$=""
FOR I=1 TO N-1
LET S$=S$&K$(I)&NUM$(I)&KK$(I)&TERM$(I)
LET F$=F$&NUM$(I)&" "
NEXT I
IF KK$(N)<>"" THEN
LET S$=S$&NUM$(N)&KK$(N)
LET F$=F$&NUM$(N)&KK$(N)
ELSE
LET S$=S$&NUM$(N)
LET F$=F$&NUM$(N)
END IF
LET I=1
LET ERR=0
CALL SKIP
LET ANS=EXPRESSION
LOOP UNTIL ERR=0 AND ANS>=0 AND ANS<=100 AND FP(ANS)=0
PRINT #2:S$;" =";ANS
PRINT #1:F$;" =";ANS
NEXT J
CLOSE #1
CLOSE #2
END

1200 MODULE interpreter
1210 PUBLIC STRING s$
1220 PUBLIC NUMERIC i,ERR
1230 PUBLIC FUNCTION expression
1240 PUBLIC SUB skip
1250 SHARE FUNCTION term,factor,primary,numeric
1260 !
1270 EXTERNAL SUB skip
1280 DO WHILE s$(i:i)=" "
1290 LET i=i+1
1300 LOOP
1310 END SUB
1320 !
1330 EXTERNAL FUNCTION expression
1340 DECLARE NUMERIC n
1350 DECLARE STRING op$
1360 SELECT CASE s$(i:i)
1370 CASE "-"
1380 LET i=i+1
1390 CALL skip
1400 LET n=-term
1410 CASE "+"
1420 LET i=i+1
1430 CALL skip
1440 LET n=term
1450 CASE ELSE
1460 LET n=term
1470 END SELECT
1480 DO WHILE s$(i:i)="+" OR s$(i:i)="-" OR S$(I:I)=">" OR S$(I:I)="<"
1490 LET op$=s$(i:i)
1500 LET i=i+1
1510 CALL skip
1520 IF op$="+" THEN LET n=n+term
IF OP$="-" THEN LET n=n-term
IF OP$="<" THEN LET N=MIN(N,TERM)
IF OP$=">" THEN LET N=MAX(N,TERM)
1530 LOOP
IF ERR=1 THEN EXIT FUNCTION
1540 LET expression =n
1550 CALL skip
1560 END FUNCTION
1570 !
1580 EXTERNAL FUNCTION term
1590 DECLARE NUMERIC n
1600 DECLARE STRING op$
1610 LET n=factor
1620 DO WHILE s$(i:i)="*" OR s$(i:i)="/" OR S$(I:I)="%" OR S$(I:I)="\" OR S$(I:I)="@"
1630 LET op$=s$(i:i)
1640 LET i=i+1
1650 CALL skip
1660 IF op$="*" THEN LET n=n*factor
IF OP$="/" THEN
LET M=FACTOR
IF M=0 THEN
LET ERR=1
EXIT FUNCTION
ELSE
LET n=n/M
END IF
END IF
IF OP$="%" THEN
LET M=FACTOR
IF M=0 THEN
LET ERR=1
EXIT FUNCTION
ELSE
LET N=MOD(N,M)
END IF
END IF
IF OP$="\" THEN
LET M=FACTOR
IF M=0 THEN
LET ERR=1
EXIT FUNCTION
ELSE
LET N=IP(N/M)
END IF
END IF
IF OP$="@" THEN LET N=(N+FACTOR)/2
1670 LOOP
1680 LET term=n
1690 END FUNCTION
1700 !
1710 EXTERNAL FUNCTION factor
1720 DECLARE NUMERIC n
1730 LET n=primary
1740 DO WHILE s$(i:i)="^" OR S$(I:I)="&" OR S$(I:I)="|" OR S$(I:I)="~"
1750 LET i=i+1
1760 CALL skip
IF OP$="^" THEN LET n=n^primary
IF OP$="&" THEN LET N=BITAND(N,PRIMARY)
IF OP$="|" THEN LET N=BITOR(N,PRIMARY)
IF OP$="~" THEN LET N=BITXOR(N,PRIMARY)
1780 LOOP
1790 LET factor=n
1800 END FUNCTION
1810 !
1820 EXTERNAL FUNCTION primary
1830 IF s$(i:i)>="0" AND s$(i:i)<="9" THEN
1840 LET primary=NUMERIC
1850 ELSEIF s$(i:i+1)="PI" THEN
1860 LET i=i+2
1870 CALL SKIP
1880 LET primary=PI
1890 ELSE
1900 IF s$(i:i)="(" THEN
1910 LET i=i+1
1920 CALL SKIP
1930 LET primary=expression
1940 ELSEIF s$(i:i+3)="SIN(" THEN
1950 LET i=i+4
1960 CALL SKIP
1970 LET Primary=SIN(expression)
1980 ELSEIF s$(i:i+3)="COS(" THEN
1990 LET i=i+4
2000 CALL SKIP
2010 LET Primary=COS(expression)
2020 ELSEIF s$(i:i+3)="TAN(" THEN
2030 LET i=i+4
2040 CALL SKIP
2050 LET Primary=TAN(expression)
2060 ELSEIF s$(i:i+3)="LOG(" THEN
2070 LET i=i+4
2080 CALL SKIP
2090 LET Primary=LOG(expression)
2100 ELSEIF s$(i:i+3)="EXP(" THEN
2110 LET i=i+4
2120 CALL SKIP
2130 LET Primary=EXP(expression)
2140 ELSEIF s$(i:i+3)="SQR(" THEN
2150 LET i=i+4
2160 CALL SKIP
2170 LET Primary=SQR(expression)
2180 ELSEIF s$(i:i+3)="INT(" THEN
2190 LET i=i+4
2200 CALL SKIP
2210 LET Primary=INT(expression)
2220 ELSEIF s$(i:i+3)="ABS(" THEN
2230 LET i=i+4
2240 CALL SKIP
2250 LET Primary=ABS(expression)
2260 ELSE
2270 LET ERR=1
2280 EXIT FUNCTION
2290 END IF
2300 IF s$(i:i)=")" THEN
2310 LET i=i+1
2320 CALL skip
2330 ELSE
2340 LET ERR=1
2350 EXIT FUNCTION
2360 END IF
2370 END IF
2380 END FUNCTION
2390 !
2400 EXTERNAL FUNCTION numeric
2410 DECLARE NUMERIC i0
2420 CALL skip
2430 LET i0=i
2440 DO WHILE s$(i:i)>="0" AND s$(i:i)<="9"
2450 LET i=i+1
2460 LOOP
2470 IF s$(i:i)="." THEN LET i=i+1
2480 DO WHILE s$(i:i)>="0" AND s$(i:i)<="9"
2490 LET i=i+1
2500 LOOP
2510 LET numeric=VAL(s$(i0:i-1))
2520 CALL skip
2530 END FUNCTION
2540 !
2550 END MODULE